Ir al contenido principal

Reto 28: La sucesión aₙ = n no está acotada

Demostrar que la sucesión \(a_{n} = n\) no está acotada.

Para ello, completar la siguiente teoría en Lean 4

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def SeqBdd (a : ℕ → ℝ) : Prop :=
  ∃ M > 0, ∀ n, |a n| ≤ M

variable {a : ℕ → ℝ}

example
  (ha : ∀ n, a n = n)
  : ¬ SeqBdd a :=
by sorry

1. Demostraciones en lenguaje natural

1ª demostración en lenguaje natural (LN1)

Supongamos que existe \(M \in \mathbb{R}\) tal que \[ \forall n, |a_n| \leq M. \tag{1} \] Por la propiedad arquimediana, existe un \(k \in ℕ\) tal que \[ M < k \tag{2} \] y recordemos que \[ \forall n, a_n = n. \tag{3} \] Entonces \[ \begin{array}{llll} M &< k &&\text{[por (2)]} \\ &= a_k &&\text{[por (3)]} \\ &\leq |a_k| \\ &\leq M &&\text{[por (1)]} \end{array} \] Por tanto, \(M < M\) que es una contradicción.

2ª demostración en lenguaje natural (LN2)

Supongamos que existe \(M \in \mathbb{R}\) tal que \[ \forall n, |a_n| \leq M. \tag{1} \] Sea \[ k = ⌈M⌉ + 1 \tag{2} \] y recordemos que \[ \forall n, a_n = n. \tag{3} \] Entonces \[ \begin{array}{llll} M &\leq ⌈M⌉ \\ &< ⌈M⌉ + 1 \\ &= k &&\text{[por (2)]} \\ &= a_k &&\text{[por (3)]} \\ &\leq |a_k| \\ &\leq M &&\text{[por (1)]} \end{array} \] Por tanto, \(M < M\) que es una contradicción.

2. Demostraciones en Lean 4

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def SeqBdd (a : ℕ → ℝ) : Prop :=
  ∃ M > 0, ∀ n, |a n| ≤ M

variable {a : ℕ → ℝ}

-- 1ª demostración (correspondiente a LN1)
-- =======================================

example
  (ha : ∀ n, a n = n)
  : ¬ SeqBdd a :=
by
  rintro ⟨M, -, hM⟩
  -- M : ℝ
  -- hM : ∀ (n : ℕ), |a n| ≤ M
  -- ⊢ False
  obtain ⟨k, hk⟩ := exists_nat_gt M
  -- k : ℕ
  -- hk : M < ↑k
  apply lt_irrefl M
  -- ⊢ M < M
  calc M
       < k         := hk
     _ = a k       := by simp [ha]
     _ ≤ |a k|     := le_abs_self _
     _ ≤ M         := hM k

-- 2ª demostración (correspondiente a LN2)
-- =======================================

example
  (ha : ∀ n, a n = n)
  : ¬ SeqBdd a :=
by
  rintro ⟨M, -, hM⟩
  -- M : ℝ
  -- hM : ∀ (n : ℕ), |a n| ≤ M
  -- ⊢ False
  set k : ℕ := ⌈M⌉₊ + 1 with hk
  apply lt_irrefl M
  -- ⊢ M < M
  calc M
       ≤ ⌈M⌉₊      := Nat.le_ceil M
     _ < k         := by simp [hk]
     _ = a k       := by simp [ha]
     _ ≤ |a k|     := le_abs_self (a k)
     _ ≤ M         := hM k

-- 3ª demostración (correspondiente a LN2)
-- =======================================

example
  (ha : ∀ n, a n = n)
  : ¬ SeqBdd a :=
by
  rintro ⟨M, -, hM⟩
  -- M : ℝ
  -- hM : ∀ (n : ℕ), |a n| ≤ M
  -- ⊢ False
  set k : ℕ := ⌈M⌉₊ + 1 with hk
  apply lt_irrefl M
  -- ⊢ M < M
  calc M
       ≤ ⌈M⌉₊      := Nat.le_ceil M
     _ < ⌈M⌉₊ + 1  := lt_add_one _
     _ = k         := by rw [hk, Nat.cast_add_one]
     _ = a k       := by rw [ha k]
     _ ≤ |a k|     := le_abs_self (a k)
     _ ≤ M         := hM k

-- 4ª demostración (correspondiente a LN2)
-- =======================================

example
  (ha : ∀ n, a n = n)
  : ¬ SeqBdd a :=
by
  rintro ⟨M, -, hM⟩
  -- M : ℝ
  -- hM : ∀ (n : ℕ), |a n| ≤ M
  -- ⊢ False
  set k : ℕ := ⌈M⌉₊ + 1
  apply lt_irrefl M
  -- ⊢ M < M
  calc M
       ≤ ⌈M⌉₊      := Nat.le_ceil M
     _ < ⌈M⌉₊ + 1  := lt_add_one (⌈M⌉₊ : ℝ)
     _ = k         := (Nat.cast_add_one ⌈M⌉₊).symm
     _ = a k       := (ha k).symm
     _ ≤ |a k|     := le_abs_self (a k)
     _ ≤ M         := hM k

Es posible consultar, modificar y ejecutar el código de estas demostraciones de forma interactiva en Lean 4 Web.

3. Soluciones colaborativas

¿Has encontrado una demostración distinta de las publicadas? Puedes compartirla en los comentarios de abajo siguiendo estos pasos:

  • Escribe tu demostración en live.lean-lang.org y comprueba que se compila sin errores.
  • Copia el código y publícalo en los comentarios de esta entrada, dentro de un bloque de código de Lean:
```lean
   -- tu demostración
```

Comentarios