Tema 11: Agentes inteligentes (representación y razonamiento)

• Mundo = Agente + Entorno (Poole–98 p. 8)
  
• Entradas del agente:
  • Conocimiento previo del mundo.
  • Experiencias anteriores de las que puede aprender.
  • Objetivos a conseguir y valores sobre lo importante.
  • Observaciones sobre su entorno y sobre sí mismo.
• Salidas del agente:
  • Acciones

• Necesidad de representación de las entradas del agente: conocimiento
• Problema ⟹ Representación ⟹ Razonamiento
• Elementos de un Sistema de representación y razonamiento:
  • Sintaxis: Lenguaje de comunicación con la computadora.
  • Semántica: Manera de asignar significado al lenguaje.
  • Cálculo: Procedimientos para obtener respuestas.
• Ejemplos de sistemas de representación y razonamiento:
  • Lenguajes de bajo nivel: Fortran, C, Lisp, …
  • Lenguaje natural

• El mundo del robot repartidor (Poole-98 p. 14)
  
• Constantes: h101, h103, h105, h107, h109, h111, h127, h129, h131

• vecina_izquierda(H1,H2) se verifica si la habitación H1 es la vecina izquierda de la habitación H2. Por ejemplo,

  ?- vecina_izquierda(h105,h107).
  true.
  
  ?- vecina_izquierda(h106,h107).
  false.
  
  ?- vecina_izquierda(X,h107).
  X = h105.
  
  ?- vecina_izquierda(h105,X).
  X = h107.
  
  ?- vecina_izquierda(h106,X).
  false.
  

  Su definición es

  vecina_izquierda(h101,h103).
  vecina_izquierda(h103,h105).
  vecina_izquierda(h105,h107).
  vecina_izquierda(h107,h109).
  vecina_izquierda(h109,h111).
  vecina_izquierda(h131,h129).
  vecina_izquierda(h129,h127).
  vecina_izquierda(h127,h125).
  

\end{verbatim}\end{sesion}

• vecina_derecha(H1,H2) que se verifica si la habitación H2 es la vecina derecha de la habitación H1. Por ejemplo,

  ?- vecina_derecha(h105,X).
  X = h103.
  

  Su definición es

  vecina_derecha(H1,H2) :- vecina_izquierda(H2,H1).
  

• vecina(H1,H2) que se verifica si la habitación H1 es vecina de la habitación H2. Por ejemplo,

  ?- vecina(X,h105).
  X = h107 ;
  X = h103.
  

  Su definición es

  vecina(H1,H2) :- vecina_derecha(H1,H2).
  vecina(H1,H2) :- vecina_izquierda(H1,H2).
  

• dos_a_la_derecha(H1,H2) que se verifica si la habitación H1 está dos a la derecha de la habitación H2. Por ejemplo,

  ?- dos_a_la_derecha(X,h105).
  X = h109 
  

  Su definición es

  dos_a_la_derecha(H1,H2) :-
     vecina_derecha(H1,H),
     vecina_derecha(H,H2).
  

• a_la_izquierda(H1,H2) que se verifica si la habitación H1 está a la izquierda de la habitación H2. Por ejemplo,

  ?- a_la_izquierda(X,h105).
  X = h103 ;
  X = h101 ;
  false.
  

  Su definición es

  a_la_izquierda(H1,H2) :-
     vecina_izquierda(H1,H2).
  a_la_izquierda(H1,H2) :-
     vecina_izquierda(H1,H),
     a_la_izquierda(H,H2).
  

• El sistema eléctrico (Poole-98 p. 16)
  
• Constantes:
  • Luces: l1, l2
  • Interruptores: i1, i2, i3
  • Cortacircuitos: cc1, cc2
  • Cables: c1, c2, c3, c4, c5, c6
  • Enchufes: e1, e2
  • Toma de corriente: entrada
• Base de conocimiento del sistema eléctrico

  • luz(L) se verifica si L es una luz.

    luz(l1).
    luz(l2).
    

  • abajo(I) se verifica si el interruptor I está hacia abajo.

    abajo(i1).
    

  • arriba(I) se verifica si el interruptor I está hacia arriba.

    arriba(i2).
    arriba(i3).
    

  • esta_bien(X) se verifica si la luz o el cortocircuito X está bien.

    esta_bien(l1).
    esta_bien(l2).
    esta_bien(cc1).
    esta_bien(cc2).
    

  • conectado(D1,D2) se verifica si los dispositivos D1 y D2 está conectados (de forma que puede fluir la corriente eléctrica de D2 a D1).

    conectado(l1,c0).
    conectado(c0,c1) :- arriba(i2).
    conectado(c0,c2) :- abajo(i2).
    conectado(c1,c3) :- arriba(i1).
    conectado(c2,c3) :- abajo(i1).
    conectado(l2,c4).
    conectado(c4,c3) :- arriba(i3).
    conectado(e1,c3).
    conectado(c3,c5) :- esta_bien(cc1).
    conectado(e2,c6).
    conectado(c6,c5) :- esta_bien(cc2).
    conectado(c5,entrada).
    

  • tiene_corriente(D) se verifica si el dispositivo D tiene corriente

    tiene_corriente(D) :-
       conectado(D,D1),
       tiene_corriente(D1).
    tiene_corriente(entrada).
    

  • esta_encendida(L) se verifica si la luz L está encendida.

    esta_encendida(L) :-
        luz(L),
        esta_bien(L),
        tiene_corriente(L).
    

• Consultas

  ?- luz(l1).
  true.
  
  ?- luz(l6).
  false.
  
  ?- arriba(X).
  X = i2 ;
  X = i3.
  
  ?- conectado(l1,D).
  D = c0.
  
  ?- conectado(c0,D).
  D = c1 ;
  false.
  
  ?- conectado(c1,D).
  false.
  
  ?- conectado(D,c3).
  D = c2 ;
  D = c4 ;
  D = e1.
  
  ?- conectado(X,Y).
  X = l1,
  Y = c0 ;
  X = c0,
  Y = c1 ;
  X = c2,
  Y = c3 ;
  X = l2,
  Y = c4 ;
  X = c4,
  Y = c3 ;
  X = e1,
  Y = c3 ;
  X = c3,
  Y = c5 ;
  X = e2,
  Y = c6 ;
  X = c6,
  Y = c5 ;
  X = c5,
  Y = entrada.
  
  ?- tiene_corriente(D).
  D = c2 ;
  D = l2 ;
  D = c4 ;
  D = e1 ;
  D = c3 ;
  D = e2 ;
  D = c6 ;
  D = c5 ;
  D = entrada.
  
  ?- esta_encendida(X).
  X = l2.
  

• W. Ertel. Introduction to artificial intelligence (2E). (Springer Verlag, 2017).
  • Cap. 1.4: Agents.
• D. Poole, A. Mackworth y R. Goebel. Computational intelligence (A logical approach). (Oxford University Press, 1998).
  • Cap. 1: Computational intelligence and knowledge.
  • Cap. 2: A representation and reasoning system.
  • Cap. 3: Using definite knowledge.
• D. Poole y A. Mackworth. Artificial intelligence: Foundations of computational agents. (Cambridge University Press, 2010).
  • Cap. 2: Agent architectures and hierarchical control.
• S. Russell y P. Norvig. Artificial intelligence: A modern approach (4th ed.). (Pearson, 2022).
  • Cap. 1: Introduction .
  • Cap. 2: Intelligent agents.
  • Cap. 7: Logical agents .
  • Cap. 10: Knowledge representation.