Ir al contenido principal

Reto 27: Si aₙ → L y M es una cota inferior de aₙ, entonces M ≤ L

Demostrar que si la sucesión \(a_n\) converge a \(L\) y \(M\) es una cota inferior de \(a_n\) (es decir, \(M \leq a_n\) para todo n), entonces \(M \leq L\).

Para ello, completar la siguiente teoría

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def SeqLim (a : ℕ → ℝ) (L : ℝ) : Prop :=
  ∀ ε > 0, ∃ k : ℕ, ∀ n ≥ k, |a n - L| < ε

variable {a : ℕ → ℝ}
variable {L M : ℝ}

example
  (ha : SeqLim a L)
  (hM : ∀ n, M ≤ a n)
  : M ≤ L :=
by sorry

1. Demostración en lenguaje natural

Lo demostramos por contradicción. Supongamos que \[ M > L \tag{1} \] y llegaremos a la contradicción \(M > M\).

De (1), se tiene \[ M - L > 0 \] y, usando esta cantidad en la convergencia de \(a_n\), se obtiene un \(k\) tal que \[ \forall n \geq k, |a_n - L| < M - L \tag{2} \] En particular, para \(n = k\) (que satisface \(k \geq k\)), de (2) se obtiene \[ |a_k - L| < M - L \tag{3} \] Además, \[ a_k - L \leq |a_k - L| \tag{4} \] ya que \(x \leq |x|\) para todo número real \(x\).

Finalmente, \[ \begin{array}{llll} M &= L + (M - L) \\ &> L + |a_k - L| &&\text{[por (3)]} \\ &\geq L + (a_k - L) &&\text{[por (4)]} \\ &= a_k \\ &\geq M &&\text{[porque \(M\) es cota inferior de \(a_n\)]} \end{array} \] Por tanto, \(M > M\), que es una contradicción.

2. Demostraciones en Lean 4

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def SeqLim (a : ℕ → ℝ) (L : ℝ) : Prop :=
  ∀ ε > 0, ∃ k : ℕ, ∀ n ≥ k, |a n - L| < ε

variable {a : ℕ → ℝ}
variable {L M : ℝ}

-- 1ª solución
-- ===========

example
  (ha : SeqLim a L)
  (hM : ∀ n, M ≤ a n)
  : M ≤ L :=
by
  by_contra hL
  -- hL : ¬M ≤ L
  -- ⊢ False
  apply lt_irrefl M
  -- ⊢ M < M
  obtain ⟨k, hk⟩ := ha (M - L) (by grind)
  -- k : ℕ
  -- hk : ∀ n ≥ k, |a n - L| < M - L
  calc M
       > a k := by grind
     _ ≥ M   := hM k

-- 2ª solución
-- ===========

example
  (ha : SeqLim a L)
  (hM : ∀ n, M ≤ a n)
  : M ≤ L :=
by
  by_contra hL
  -- hL : ¬M ≤ L
  -- ⊢ False
  apply lt_irrefl M
  -- ⊢ M < M
  have h1 : M > L := not_le.mp hL
  have h2 : M - L > 0 := sub_pos.mpr h1
  obtain ⟨k, hk⟩ := ha (M - L) h2
  -- k : ℕ
  -- hk : ∀ n ≥ k, |a n - L| < M - L
  calc M
       = L + (M - L)    := by grind
     _ > L + |a k - L|  := by grind
     _ ≥ L + (a k - L)  := by grind
     _ = a k            := by grind
     _ ≥ M              := hM k

-- 3ª solución
-- ===========

example
  (ha : SeqLim a L)
  (hM : ∀ n, M ≤ a n)
  : M ≤ L :=
by
  by_contra hL
  -- hL : ¬M ≤ L
  -- ⊢ False
  apply lt_irrefl M
  -- ⊢ M < M
  have h1 : M - L > 0 := sub_pos.mpr (not_le.mp hL)
  obtain ⟨k, hk⟩ := ha (M - L) h1
  -- k : ℕ
  -- hk : ∀ n ≥ k, |a n - L| < M - L
  have h2 : |a k - L| < M - L := hk k (le_refl k)
  have h3 : a k - L ≤ |a k - L| := le_abs_self (a k - L)
  calc M
       = L + (M - L)    := by ring
     _ > L + |a k - L|  := add_lt_add_right h2 L
     _ ≥ L + (a k - L)  := by gcongr
     _ = a k            := by ring
     _ ≥ M              := hM k

-- 4ª solución
-- ===========

example
  (ha : SeqLim a L)
  (hM : ∀ n, M ≤ a n)
  : M ≤ L :=
by
  by_contra hL
  -- hL : ¬M ≤ L
  -- ⊢ False
  apply lt_irrefl M
  -- ⊢ M < M
  obtain ⟨k, hk⟩ := ha (M - L) (sub_pos.mpr (not_le.mp hL))
  -- k : ℕ
  -- hk : ∀ n ≥ k, |a n - L| < M - L
  have h1 : |a k - L| < M - L := hk k (le_refl k)
  have h2 : a k - L ≤ |a k - L| := le_abs_self (a k - L)
  calc M
       = L + (M - L)    := (add_sub_cancel L M).symm
     _ > L + |a k - L|  := add_lt_add_right h1 L
     _ ≥ L + (a k - L)  := (add_le_add_iff_left L).mpr h2
     _ = a k            := add_sub_cancel L (a k)
     _ ≥ M              := hM k

Es posible consultar, modificar y ejecutar el código de estas demostraciones de forma interactiva en Lean 4 Web.

3. Soluciones colaborativas

¿Has encontrado una demostración distinta de las publicadas? Puedes compartirla en los comentarios de abajo siguiendo estos pasos:

  • Escribe tu demostración en live.lean-lang.org y comprueba que se compila sin errores.
  • Copia el código y publícalo en los comentarios de esta entrada, dentro de un bloque de código de Lean:
```lean
   -- tu demostración
```

Comentarios