Ir al contenido principal

Reto 29: Si aₙ y bₙ son sucesiones de Cauchy, entonces aₙ+bₙ también lo es

Demostrar que si \(a_n\) y \(b_n\) son sucesiones de Cauchy, entonces su suma \(a_n + b_n\) también lo es.

Para ello, completar la siguiente teoría

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def IsCauchy (a : ℕ → ℝ) : Prop :=
  ∀ (ε : ℝ), 0 < ε → ∃ N : ℕ, ∀ n ≥ N, ∀ m ≥ N, |a m - a n| < ε

variable {a b : ℕ → ℝ}

example
  (ha : IsCauchy a)
  (hb : IsCauchy b)
  : IsCauchy (a + b) :=
by sorry

1. Demostración en lenguaje natural

Sea \(\varepsilon \in \mathbb{R}\) tal que \[ \varepsilon > 0 \tag{1} \] Tenemos que demostrar que existe un \(N \in \mathbb{N}\) tal que \[ \forall n \geq N, \forall m \geq N, |(a + b)(m) - (a + b)(n)| < \varepsilon \tag{2} \]

Por (1), se tiene que \[ \dfrac{\varepsilon}{2} > 0 \tag{3} \] y, puesto que \(a_n\) es de Cauchy, existe un \(N_1\) tal que \[ \forall n \geq N_1, \forall m \geq N_1, |a(m) - a(n)| < \dfrac{\varepsilon}{2} \tag{4} \] y, puesto que \(b_n\) es de Cauchy, existe un \(N_2\) tal que \[ \forall n \geq N_2, \forall m \geq N_2, |b(m) - b(n)| < \dfrac{\varepsilon}{2} \tag{5} \] Sea \[ N = máx(N_1, N_2) \tag{6} \] Veamos que con \(N\) se verifica (2). Para ello, sean \(n\) y \(m\) tales que \[ n \geq N \tag{7} \] \[ m \geq N \tag{8} \] Por (7), (8) y (6), se tiene que \[ n \geq N_1 \text{ y } m \geq N_1 \] y, por (4), se tiene que \[ |a(m) - a(n)| < \dfrac{\varepsilon}{2} \tag{9} \] Por (7), (8) y (6), también se tiene que \[ n \geq N_2 \text{ y } m \geq N_2 \] y, por (5), se tiene que \[ |b(m) - b(n)| < \dfrac{\varepsilon}{2} \tag{10} \] Finalmente, \[ \begin{array}{llll} |(a + b)(m) - (a + b)(n)| &= |(a(m) - a(n)) + (b(m) - b(n))| \\ &≤ |a(m) - a(n)| + |b(m) - b(n)| &&\text{[por la desigualdad triangular]}\\ &< \dfrac{\varepsilon}{2} + \dfrac{\varepsilon}{2} &&\text{[por (9) y (10)]} \\ &= \varepsilon \end{array} \]

2. Demostraciones en Lean 4

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def IsCauchy (a : ℕ → ℝ) : Prop :=
  ∀ (ε : ℝ), 0 < ε → ∃ N : ℕ, ∀ n ≥ N, ∀ m ≥ N, |a m - a n| < ε

variable {a b : ℕ → ℝ}

-- 1ª demostración
-- ===============

example
  (ha : IsCauchy a)
  (hb : IsCauchy b)
  : IsCauchy (a + b) :=
by
  intro ε hε
  -- ε : ℝ
  -- hε : 0 < ε
  -- ⊢ ∃ N, ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  obtain ⟨N1, hN1⟩ := ha (ε/2) (by positivity)
  -- N1 : ℕ
  -- hN1 : ∀ n ≥ N1, ∀ m ≥ N1, |a m - a n| < ε / 2
  obtain ⟨N2, hN2⟩ := hb (ε/2) (by positivity)
  -- N2 : ℕ
  -- hN2 : ∀ n ≥ N2, ∀ m ≥ N2, |b m - b n| < ε / 2
  set N := max N1 N2
  use N
  -- ⊢ ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  intro n hn m hm
  -- n : ℕ
  -- hn : n ≥ N
  -- m : ℕ
  -- hm : m ≥ N
  -- ⊢ |(a + b) m - (a + b) n| < ε
  calc |(a + b) m - (a + b) n|
       = |(a m + b m) - (a n + b n)| := rfl
     _ = |(a m - a n) + (b m - b n)| := by congr; ring
     _ ≤ |a m - a n| + |b m - b n|   := abs_add_le _ _
     _ < ε/2 + ε/2                   := by grind
     _ = ε                           := by grind

-- 2ª demostración
-- ===============

example
  (ha : IsCauchy a)
  (hb : IsCauchy b)
  : IsCauchy (a + b) :=
by
  intro ε hε
  -- ε : ℝ
  -- hε : 0 < ε
  -- ⊢ ∃ N, ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  obtain ⟨N1, hN1⟩ := ha (ε/2) (by positivity)
  -- N1 : ℕ
  -- hN1 : ∀ n ≥ N1, ∀ m ≥ N1, |a m - a n| < ε / 2
  obtain ⟨N2, hN2⟩ := hb (ε/2) (by positivity)
  -- N2 : ℕ
  -- hN2 : ∀ n ≥ N2, ∀ m ≥ N2, |b m - b n| < ε / 2
  set N := max N1 N2
  use N
  -- ⊢ ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  intro n hn m hm
  -- n : ℕ
  -- hn : n ≥ N
  -- m : ℕ
  -- hm : m ≥ N
  -- ⊢ |(a + b) m - (a + b) n| < ε
  have h1 : |a m - a n| < ε/2 := by
    apply hN1
    · -- ⊢ m ≥ N1
      exact le_of_max_le_left hn
    · -- ⊢ m ≥ N1
      exact le_of_max_le_left hm
  have h2 : |b m - b n| < ε/2 := by
    apply hN2
    · -- ⊢ n ≥ N2
      exact le_of_max_le_right hn
    · -- ⊢ m ≥ N2
      exact le_of_max_le_right hm
  calc |(a + b) m - (a + b) n|
       = |(a m + b m) - (a n + b n)| := rfl
     _ = |(a m - a n) + (b m - b n)| := by congr; ring
     _ ≤ |a m - a n| + |b m - b n|   := abs_add_le _ _
     _ < ε/2 + ε/2                   := by gcongr
     _ = ε                           := by ring

-- 3ª demostración
-- ===============

theorem isCauchy_add
  (ha : IsCauchy a)
  (hb : IsCauchy b)
  : IsCauchy (a + b) :=
by
  intro ε hε
  -- ε : ℝ
  -- hε : 0 < ε
  -- ⊢ ∃ N, ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  obtain ⟨N1, hN1⟩ := ha (ε/2) (half_pos hε)
  -- N1 : ℕ
  -- hN1 : ∀ n ≥ N1, ∀ m ≥ N1, |a m - a n| < ε / 2
  obtain ⟨N2, hN2⟩ := hb (ε/2) (half_pos hε)
  -- N2 : ℕ
  -- hN2 : ∀ n ≥ N2, ∀ m ≥ N2, |b m - b n| < ε / 2
  set N := max N1 N2
  use N
  -- ⊢ ∀ n ≥ N, ∀ m ≥ N, |(a + b) m - (a + b) n| < ε
  intro n hn m hm
  -- n : ℕ
  -- hn : n ≥ N
  -- m : ℕ
  -- hm : m ≥ N
  -- ⊢ |(a + b) m - (a + b) n| < ε
  have h1 : |a m - a n| < ε/2 :=
    hN1 n (le_of_max_le_left hn) m (le_of_max_le_left hm)
  have h2 : |b m - b n| < ε/2 :=
    hN2 n (le_of_max_le_right hn) m (le_of_max_le_right hm)
  calc |(a + b) m - (a + b) n|
       = |(a m + b m) - (a n + b n)| :=
           rfl
     _ = |(a m - a n) + (b m - b n)| :=
           congrArg abs (add_sub_add_comm (a m) (b m) (a n) (b n))
     _ ≤ |a m - a n| + |b m - b n| :=
           abs_add_le (a m - a n) (b m - b n)
     _ < ε/2 + ε/2 :=
           add_lt_add h1 h2
     _ = ε :=
           add_halves ε

Es posible consultar, modificar y ejecutar el código de estas demostraciones de forma interactiva en Lean 4 Web.

3. Soluciones colaborativas

¿Has encontrado una demostración distinta de las publicadas? Puedes compartirla en los comentarios de abajo siguiendo estos pasos:

  • Escribe tu demostración en live.lean-lang.org y comprueba que se compila sin errores.
  • Copia el código y publícalo en los comentarios de esta entrada, dentro de un bloque de código de Lean:
```lean
   -- tu demostración
```

Comentarios