Ir al contenido principal

Reto 30: Las sucesiones de Cauchy están acotadas

Demostrar que si una sucesión \(a_n\) es de Cauchy, entonces \(a_n\) está acotada; es decir, existe un \(M \in \mathbb{R}\) tal que para todo \(n \in \mathbb{N}\), \(|a_n| \leq M\).

Para ello, completar la siguiente teoría

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def IsCauchy (a : ℕ → ℝ) : Prop :=
  ∀ (ε : ℝ), 0 < ε → ∃ N : ℕ, ∀ n ≥ N, ∀ m ≥ N, |a m - a n| < ε

def SeqBdd (a : ℕ → ℝ) : Prop :=
  ∃ M > 0, ∀ n, |a n| ≤ M

open Finset

variable (a : ℕ → ℝ)
example
  (ha : IsCauchy a)
  : SeqBdd a :=
by sorry

1. Demostración en lenguaje natural

La demostración se basa en los siguientes lemas: + Lema 1: Si \(a_n\) es de Cauchy, entonces existe un \(k \in \mathbb{N}\) tal que \[ \forall n \geq k, |a_n| < |a_k| + 1 \] + Lema 2: Para cada \(k \in \mathbb{N}\), existe un \(M \in \mathbb{R}\) tal que \[ \forall i < k, |a_i| \leq M \]

En efecto, por el lema 1, existe un \(k \in \mathbb{N}\) tal que \[ \forall n \geq k, |a_n| < |aₖ| + 1 \tag{1} \] Además, por el Lema 2, existe un \(C \in \mathbb{R}\) tal que \[ \forall i < k, |aᵢ| \leq C \tag{2} \] Sea \[ M = \max(|aₖ| + 1, C) \tag{3} \] Veamos en primer lugar que \(M > 0\). En efecto, \[ \begin{array}{llll} M &\geq |aₖ| + 1 &&\text{[por (3)]} \\ &\geq 0 + 1 \\ &= 1 \\ &> 0 \end{array} \]

En segundo lugar, veamos que para todo \(n \in \mathbb{N}\), \(|a_n| \leq M\). Lo haremos distinguiendo dos casos.

Caso 1: Supongamos que \(n < k\). Entonces, \[ \begin{array}{llll} |a_n| &\leq C &&\text{[por (2)]} \\ &\leq M &&\text{[por (3)]} \end{array} \]

Caso 2: Supongamos que \(n \geq k\). Entonces, \[ \begin{array}{llll} |a_n| &\leq |aₖ| + 1 &&\text{[por (1)]} \\ &\leq M &&\text{[por (3)]} \end{array} \]

Falta la demostración de los lemas. Para demostrar el primer lema, puesto que \(a_n\) es de Cauchy, existe un \(k \in \mathbb{N}\) tal que \[ \forall i \geq k, \forall j \geq i, |aᵢ - aⱼ| < 1 \tag{4} \] Veamos que \(k\) cumple la condición; es decir, \[ \forall n \geq k, |a_n| < |a_k| + 1 \] Para ello, sea \(n \in \mathbb{N}\) tal que \[ n \geq k \] Entonces, por (4) y por ser \(k \geq k\), se tiene \[ |a_n - a_k| < 1 \tag{5} \] y, por tanto, \[ \begin{array}{llll} |a_n| &= |a_k + (a_n - a_k)| \\ &\leq |a_k| + |a_n - a_k| &&\text{[por la desigualdad triangular]} \\ &< |a_k| + 1 &&\text{[por (5)]} \end{array} \]

Para demostrar el lema 2, sea \[M = \sum_{i \in \mathrm{range}(k)} |a_i| \tag{6} \] es decir, \[ M = |a_0| + |a_1| + \dots + |a_{k-1}| \] Veamos que \(M\) es la cota buscada; es decir, \[ \forall i < k, |a_i| \leq M \] Para ello, sea \(i \in \mathbb{N}\) tal que \[ i < k \tag{7} \] Entonces, puesto que \[ \forall i \in \mathrm{range}(k), 0 \leq |a_i| \tag{8} \] y, por (7), \[ i \in \mathrm{range}(k) \tag{9} \] se tiene que \[ \begin{array}{llll} |a_i| &\leq \sum_{i \in \mathrm{range}(k)} |a_i| &&\text{[por (8) y (9)]}\\ &= M &&\text{[por (6)]} \end{array} \]

2. Demostraciones en Lean 4

import Mathlib.Basic.Real.Basic
import Mathlib.Tactic

def IsCauchy (a : ℕ → ℝ) : Prop :=
  ∀ (ε : ℝ), 0 < ε → ∃ N : ℕ, ∀ n ≥ N, ∀ m ≥ N, |a m - a n| < ε

def SeqBdd (a : ℕ → ℝ) : Prop :=
  ∃ M > 0, ∀ n, |a n| ≤ M

open Finset

variable (a : ℕ → ℝ)

lemma cauchy_exists_bound_tail_terms
  (h : IsCauchy a)
  : ∃ k, ∀ n ≥ k, |a n| < |a k| + 1 :=
by
  obtain ⟨k, hk⟩ := h 1 one_pos
  -- k : ℕ
  -- hk : ∀ n ≥ k, ∀ m ≥ k, |a m - a n| < 1
  use k
  -- ⊢ ∀ n ≥ k, |a n| < |a k| + 1
  intro n hn
  -- n : ℕ
  -- hn : n ≥ k
  -- ⊢ |a n| < |a k| + 1
  have h1 : |a n - a k| < 1 := hk k (le_refl k) n hn
  calc |a n|
       = |a k + (a n - a k)| := congrArg abs (add_sub_cancel (a k) (a n)).symm
     _ ≤ |a k| + |a n - a k| := abs_add_le (a k) (a n - a k)
     _ < |a k| + 1           := add_lt_add_right h1 |a k|

lemma exists_bound_first_terms
  (k : ℕ)
  : ∃ M, ∀ i < k, |a i| ≤ M :=
  ⟨∑ i ∈ range k, |a i|,
   fun _ hi => single_le_sum
                 (fun j _ => abs_nonneg (a j))
                 (mem_range.mpr hi)⟩

example
  (ha : IsCauchy a)
  : SeqBdd a :=
by
  obtain ⟨k, hk⟩ := cauchy_exists_bound_tail_terms a ha
  -- k : ℕ
  -- hk : ∀ n ≥ k, |a n| < |a k| + 1
  obtain ⟨C, hC⟩ := exists_bound_first_terms a k
  -- C : ℝ
  -- hC : ∀ i < k, |a i| ≤ C
  set M := max (|a k| + 1) C
  use M
  -- ⊢ M > 0 ∧ ∀ (n : ℕ), |a n| ≤ M
  constructor
  · -- ⊢ M > 0
    calc M
         ≥ |a k| + 1 := le_max_left (|a k| + 1) C
       _ ≥ 0 + 1     := add_le_add_left (abs_nonneg (a k)) 1
       _ = 1         := zero_add 1
       _ > 0         := Real.zero_lt_one
  · intro n
    -- n : ℕ
    -- ⊢ |a n| ≤ M
    rcases lt_or_ge n k with hn1 | hn2
    · -- hn1 : n < k
      calc |a n|
           ≤ C := hC n hn1
         _ ≤ M := le_max_right (|a k| + 1) C
    · -- hn2 : k ≤ n
      calc |a n|
           ≤ |a k| + 1 := le_of_lt (hk n hn2)
         _ ≤ M         := le_max_left (|a k| + 1) _

Es posible consultar, modificar y ejecutar el código de estas demostraciones de forma interactiva en Lean 4 Web.

3. Soluciones colaborativas

¿Has encontrado una demostración distinta de las publicadas? Puedes compartirla en los comentarios de abajo siguiendo estos pasos:

  • Escribe tu demostración en live.lean-lang.org y comprueba que se compila sin errores.
  • Copia el código y publícalo en los comentarios de esta entrada, dentro de un bloque de código de Lean:
```lean
   -- tu demostración
```

Comentarios